justfile

set default-list

# Compile Tailwind css, then build the site with Zola
build: build-tailwind
    zola build

# Generate Tailwind static/style.css from css/style.css
build-tailwind:
    npm run tailwind:build

# Try to build site without rendering (checks links)
check:
    zola check

# Run Tailwind watch and Zola live serve in parallel
dev:
    npm run dev

# Clear public directory generated by Zola
reset:
    rm -rf public

# Install Node.js dependencies
install: npm basecoat
    @echo "Successfully installed dependencies and copied basecoat files to static."

[private]
npm:
    npm install

[private]
basecoat:
    mkdir -p static/js/
    cp node_modules/basecoat-css/dist/js/*.js static/js/

# Create a new documentation page at content/{{path}}.qmd
page path:
    #!/usr/bin/env bash
    set -euo pipefail
    if [ -f "content/{{ path }}.qmd" ]; then
    	@echo "Error: content/{{ path }}.qmd already exists."
    	exit 1
    fi
    cat > "content/{{ path }}.qmd" <<-EOF
    ---
    title:
    description: ""
    weight: 0
    extra:
      short_title:
    ---
    EOF
    @echo "Created content/{{ path }}.qmd"

# Create a new blog post at content/blog/{{title}}/index.qmd
post title:
    #!/usr/bin/env bash
    set -euo pipefail
    date=$(date +%Y-%m-%d)
    dir="content/blog/${date}-{{ title }}"
    mkdir -p "$dir"
    cat > "$dir/index.qmd" <<-EOF
    ---
    title: {{ title }}
    date: "$date"
    authors: []
    taxonomies:
      tags: []
    ---
    EOF
    @echo "Created $dir/index.qmd"

# Render a documentation page at content/{{path}}.qmd
render-page path: (render-one path)

# Render a blog post at content/blog/{{title}}/index.qmd
render-post title: (render-one ("blog" / title / "index"))

[private]
render-one path:
    #!/usr/bin/env bash
    set -euo pipefail
    cd content
    if [ -f "{{ path }}.qmd" ]; then
    	rm -f "{{ path }}.md"
    	quarto render "{{ path }}.qmd" {{ quarto_out + " " + quarto_flags }}
    else
    	@echo "Error: Could not find content/{{ path }}.qmd."
    	exit 1
    fi

# Render all pages in content/ recursively (ignores blog/)
render:
    #!/usr/bin/env bash
    set -euo pipefail
    shopt -s globstar nullglob
    cd content
    for page in **/*.qmd; do
    	[[ "$page" == blog/* ]] && continue
    	rm -f "${page%.qmd}.md"
    	quarto render "$page" {{ quarto_out + " " + quarto_flags }}
    done
    @echo "Successfully rendered all documentation pages."

quarto_out := "--to commonmark+yaml_metadata_block"
quarto_flags := "-M engine:knitr -M wrap:preserve -M from:markdown-smart"