Fix for 126457 (#127050)

For a bool-typed inlinee that contains a tail call, where the return is
in a seperate block from the tailcall (for a single-return method, for
example), the inliner inserts an int->ubyte->int normalizing cast

```
*  RETURN  int
\--*  CAST    int <- ubyte <- int
   \--*  LCL_VAR int    V04 tmp3
```

The tail-call validation in morph doesn't expect a cast there. However,
a normalizing cast here may be safely ignored for tailcalls because
1 - If the calling function was not inlined, the normalizing cast is
intead inserted later in morph after the tailcall transformation, and
2 - Callees are responsible for this adjustment anyway so the tailcall
return value would have already been normalized

fixes #126457

Author: dhartglassMSFT

src/coreclr/jit/morph.cpp

@@ -5040,6 +5040,15 @@ void Compiler::fgValidateIRForTailCall(GenTreeCall* call)
             {
                 assert(ValidateUse(tree) && "Expected use of local to be tailcall value");
             }
+            else if (tree->OperIs(GT_CAST))
+            {
+                // The inliner can insert small-type-normalizing casts before the return
+                // (int -> ubyte -> int for bool-return-calls, for example)
+                // In the jit the callee is responsible for normalizing, so a tailcall
+                // can freely bypass this extra cast
+                assert(!m_compiler->fgCastNeeded(m_tailcall, tree->AsCast()->CastToType()) &&
+                       ValidateUse(tree->AsCast()->CastOp()) && "Expected normalizing cast of tailcall result");
+            }
             else if (IsCommaNop(tree))
             {
                 // COMMA(NOP,NOP)
@@ -5065,6 +5074,11 @@ void Compiler::fgValidateIRForTailCall(GenTreeCall* call)
 
         bool ValidateUse(GenTree* node)
         {
+            if (node->OperIs(GT_CAST))
+            {
+                node = node->AsCast()->CastOp();
+            }
+
             if (m_lclNum != BAD_VAR_NUM)
             {
                 return node->OperIs(GT_LCL_VAR) && (node->AsLclVar()->GetLclNum() == m_lclNum);

src/tests/JIT/Regression/JitBlue/Runtime_126457/Runtime_126457.il

@@ -0,0 +1,98 @@
+// Licensed to the .NET Foundation under one or more agreements.
+// The .NET Foundation licenses this file to you under the MIT license.
+
+// In some cases the Inliner can insert a CAST node between
+// a tail call and the return
+
+.assembly extern System.Runtime
+{
+  .publickeytoken = (B0 3F 5F 7F 11 D5 0A 3A)
+}
+
+.assembly Runtime_126457 { }
+.module Runtime_126457.dll
+
+.class interface public abstract auto ansi ISite
+{
+  .method public hidebysig newslot abstract virtual
+    instance bool tailcall() cil managed
+  {
+  }
+}
+
+.class public auto ansi beforefieldinit Component
+       extends [System.Runtime]System.Object
+{
+  .field family class ISite _site
+
+  .method family hidebysig newslot virtual
+    instance bool callee() cil managed
+  {
+    .maxstack 8
+    ldarg.0
+    ldfld      class ISite Component::_site
+    dup
+    brtrue.s   CALL
+    pop
+    ldc.i4.0
+    br.s       DONE
+  CALL:
+    callvirt   instance bool ISite::tailcall()
+  DONE:
+    ret
+  }
+
+  .method public hidebysig specialname rtspecialname
+    instance void .ctor() cil managed
+  {
+    ldarg.0
+    call instance void [System.Runtime]System.Object::.ctor()
+    ret
+  }
+}
+
+.class public auto ansi beforefieldinit DerivedComponent
+       extends Component
+{
+  .method public hidebysig virtual
+    instance bool caller() cil managed
+  {
+    .maxstack 8
+    ldarg.0
+    call instance bool Component::callee()
+    ret
+  }
+
+  .method public hidebysig specialname rtspecialname
+    instance void .ctor() cil managed
+  {
+    ldarg.0
+    call instance void Component::.ctor()
+    ret
+  }
+}
+
+.class private auto ansi beforefieldinit Program
+       extends [System.Runtime]System.Object
+{
+  .method private hidebysig static int32
+    Main() cil managed
+  {
+    .entrypoint
+    .maxstack 1
+    newobj instance void DerivedComponent::.ctor()
+    call bool Program::Test(class DerivedComponent)
+    pop
+    ldc.i4.s 100
+    ret
+  }
+
+  .method private hidebysig static bool
+    Test(class DerivedComponent c) cil managed noinlining
+  {
+    .maxstack 8
+    ldarg.0
+    callvirt instance bool DerivedComponent::caller()
+    ret
+  }
+}

src/tests/JIT/Regression/JitBlue/Runtime_126457/Runtime_126457.ilproj

@@ -0,0 +1,14 @@
+<Project Sdk="Microsoft.NET.Sdk.IL">
+  <PropertyGroup>
+    <RequiresProcessIsolation>true</RequiresProcessIsolation>
+  </PropertyGroup>
+  <PropertyGroup>
+    <DebugType>None</DebugType>
+    <Optimize>True</Optimize>
+  </PropertyGroup>
+  <ItemGroup>
+    <Compile Include="$(MSBuildProjectName).il" />
+
+    <CLRTestEnvironmentVariable Include="DOTNET_TieredCompilation" Value="0" />
+  </ItemGroup>
+</Project>